arch-signoff/repos/extra-any/PKGBUILD

   1 # Maintainer: Jelle van der Waa <jelle@archlinux.org>
   2
   3 pkgname=arch-signoff
   4 pkgver=0.5.2
   5 pkgrel=3
   6 pkgdesc='Sign off Arch Linux testing packages'
   7 arch=(any)
   8 url="https://github.com/archlinux/arch-signoff"
   9 license=("custom:ISC")
  10 depends=('python' 'pyalpm' 'python-click' 'python-dateutil'
  11          'python-requests')
  12 makedepends=('python-setuptools-scm' 'asciidoc' 'git')
  13 checkdepends=('python-pytest-pacman' 'python-pytest' 'python-pytest-cov')
  14 groups=('archlinux-tools')
  15 source=("$pkgname::git+https://github.com/archlinux/arch-signoff.git?signed#tag=$pkgver")
  16 validpgpkeys=(
  17     'E499C79F53C96A54E572FEE1C06086337C50773E' # Jelle van der Waa
  18 )
  19 md5sums=('SKIP')
  20
  21 build() {
  22   cd "$pkgname"
  23   python setup.py build
  24   make -C man
  25 }
  26
  27 check() {
  28   cd "$pkgname"
  29   make test
  30 }
  31
  32 package() {
  33   cd "$pkgname"
  34   python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
  35
  36   install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  37   install -Dm644 "man/signoff.1" "$pkgdir/usr/share/man/man1/signoff.1"
  38 }