babl/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Daniel Isenmann <daniel@archlinux.org>
   2
   3 pkgname=babl
   4 _tag='ddb6912548e1490edc9638a37b1fa4f16b5e044b'
   5 pkgver=0.1.104
   6 pkgrel=1
   7 pkgdesc='Dynamic, any to any, pixel format conversion library'
   8 arch=('x86_64')
   9 url='https://gegl.org/babl/'
  10 license=('LGPL3')
  11 depends=('glibc' 'lcms2')
  12 makedepends=('git' 'meson' 'gobject-introspection' 'vala')
  13 source=("git+https://gitlab.gnome.org/GNOME/babl.git#tag=$_tag")
  14 sha256sums=('SKIP')
  15
  16 pkgver() {
  17   cd "${pkgname}"
  18   git describe --tags | sed 's/^BABL_//;s/_$//;s/_/./g;s/-/+/g'
  19 }
  20
  21 prepare() {
  22   # https://gitlab.gnome.org/GNOME/babl/-/merge_requests/45
  23   sed -i s/Description/description/ "${pkgname}"/meson.build
  24 }
  25
  26 build() {
  27   arch-meson "${pkgname}" build
  28   ninja -C build
  29 }
  30
  31 check() {
  32   meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36   DESTDIR="${pkgdir}" meson install -C build
  37 }