haveged/trunk/PKGBUILD

   1 # Maintainer:  Christian Hesse <mail@eworm.de>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: kfgz <kfgz at interia dot pl>
   4 # Contributor: pootzko <pootzko at gmail dot com>
   5
   6 pkgname=haveged
   7 pkgver=1.9.18
   8 pkgrel=1
   9 pkgdesc='Entropy harvesting daemon using CPU timings'
  10 arch=('x86_64')
  11 url='https://github.com/jirka-h/haveged'
  12 license=('GPL')
  13 depends=('glibc')
  14 validpgpkeys=('8F6B7293B03E5AC5762B65CE2E2F252B05CCA168') # Jirka Hladky <hladky.jiri@gmail.com>
  15 source=("$pkgname-$pkgver.tar.gz::https://github.com/jirka-h/$pkgname/archive/v$pkgver.tar.gz"
  16         'initcpio-hook'
  17         'initcpio-install')
  18 sha256sums=('b835fa02b52ee7d06276e028571cadcb14d08f5e5a4b5767adf81451f70561c7'
  19             'a59ff95d521a860031693d1e1d65d37ffba58412f0199b029bd340e2f7f52a0b'
  20             'befb42d418d13c832da6d67f50417f6bca9a1c754dbdc63175f1e2546ea29b51')
  21
  22 prepare() {
  23   cd $pkgname-$pkgver
  24
  25   sed -i 's/@SBIN_DIR@/\/usr\/bin/' contrib/Fedora/haveged*.service
  26 }
  27
  28 build() {
  29   cd $pkgname-$pkgver
  30
  31   ./configure \
  32       --prefix=/usr \
  33       --bindir=/usr/bin \
  34       --sbindir=/usr/bin
  35   make
  36 }
  37
  38 check() {
  39   cd ${pkgname}-${pkgver}
  40   make check
  41 }
  42
  43 package() {
  44   cd $pkgname-$pkgver
  45
  46   make DESTDIR="$pkgdir" install
  47
  48   install -D -m0644 contrib/Fedora/haveged.service "$pkgdir"/usr/lib/systemd/system/haveged.service
  49   install -D -m0644 contrib/Fedora/haveged-once.service "$pkgdir"/usr/lib/systemd/system/haveged-once.service
  50   install -D -m0644 "${srcdir}/initcpio-hook" "$pkgdir"/usr/lib/initcpio/hooks/haveged
  51   install -D -m0644 "${srcdir}/initcpio-install" "$pkgdir"/usr/lib/initcpio/install/haveged
  52 }