imlib2/trunk/PKGBUILD

   1 # Maintainer: Ronald van Haren <ronald.archlinux.org>
   2 # Contributor: Arjan Timmerman <arjan.archlinux.org>
   3 # Contributor: Tom Newsom <Jeepster.gmx.co.uk>
   4
   5 pkgname=imlib2
   6 pkgver=1.11.1
   7 pkgrel=1
   8 pkgdesc='Library that does image file loading and saving as well as rendering, manipulation, arbitrary polygon support'
   9 url='https://sourceforge.net/projects/enlightenment/'
  10 arch=('x86_64')
  11 license=('BSD')
  12 makedepends=(# Currently highway does provide a static library only, that libjxl links to.
  13              # This introduces a build dependency for now...
  14              'highway'
  15              'libheif' 'libid3tag' 'libjxl' 'librsvg' 'libspectre' 'libwebp' 'openjpeg2')
  16 depends=('bzip2' 'freetype2' 'giflib' 'libjpeg-turbo' 'libpng' 'libtiff' 'libxext' 'xz')
  17 optdepends=('libheif: HEIF loader (for AVIF)'
  18             'libid3tag: ID3 loader'
  19             'libjxl: JXL loader'
  20             'librsvg: SVG loader'
  21             'libspectre: PS loader'
  22             'libwebp: WEBP loader'
  23             'openjpeg2: J2K loader')
  24 source=("https://downloads.sourceforge.net/project/enlightenment/imlib2-src/${pkgver}/${pkgname}-${pkgver}.tar.xz")
  25 sha256sums=('f712b6bb9dcad46d8b8f4ad52610dcbbaebb4cc80b5fd12f93124d3a380fa6bf')
  26 sha512sums=('2d0dc569ab35822d5ac3cd07979a807462c1ad501ea15e4c757a15bbe254657c08acf6da8603ba2e9ab5b57a6b0c0ecf119eab80ffe59a55f29d325c839763ac')
  27
  28 build() {
  29   cd "${pkgname}-${pkgver}"
  30
  31   ./configure \
  32     --prefix=/usr \
  33     --sysconfdir=/etc/imlib2 \
  34     --x-libraries=/usr/lib \
  35     --enable-amd64
  36   make
  37 }
  38
  39
  40 check() {
  41   cd "${pkgname}-${pkgver}"
  42   make check
  43 }
  44
  45
  46 package() {
  47   cd "${pkgname}-${pkgver}"
  48   make DESTDIR="${pkgdir}" install
  49
  50   # Install License
  51   install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  52 }