liboauth/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Kaiting Chen <kaitocracy@gmail.com>
   3 # Contributor: Martin Häger <martin.haeger@gmail.com>
   4
   5 pkgname=liboauth
   6 pkgver=1.0.3+r16+gc26f038
   7 pkgrel=1
   8 epoch=1
   9 pkgdesc="C library implementing OAuth Core RFC 5849"
  10 url="https://github.com/x42/liboauth"
  11 arch=(x86_64)
  12 license=(MIT)
  13 depends=(curl nss)
  14 makedepends=(git)
  15 _commit=c26f038eb9a4d97782e3f9f1e3da2b9356581869  # master
  16 source=("git+$url#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 prepare() {
  20   cd liboauth
  21   autoreconf -fvi
  22 }
  23
  24 pkgver() {
  25   cd liboauth
  26   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  27 }
  28
  29 build() {
  30   cd liboauth
  31   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  32     --disable-static --enable-nss
  33   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  34   make
  35 }
  36
  37 check() {
  38   cd liboauth
  39   make check
  40 }
  41
  42 package() {
  43   cd liboauth
  44   make DESTDIR="$pkgdir" install
  45   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING.MIT
  46 }
  47
  48 # vim:set sw=2 sts=-1 et: