ntp/trunk/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: kevin <kevin@archlinux.org>
   4
   5 pkgname=ntp
   6 _pkgname=ntp #-dev
   7 _pkgver=4.2.8p15
   8 pkgver=${_pkgver/p/.p}
   9 pkgrel=3
  10 pkgdesc='Network Time Protocol reference implementation'
  11 url='http://www.ntp.org/'
  12 license=('custom')
  13 arch=('x86_64')
  14 depends=('openssl' 'perl' 'libcap' 'libedit')
  15 backup=('etc/ntp.conf')
  16 source=("https://www.eecis.udel.edu/~ntp/ntp_spool/ntp4/ntp-4.2/${_pkgname}-${_pkgver}.tar.gz"
  17         'ntp-4.2.8_p15-glibc-2.34.patch'
  18         'ntp.conf'
  19         'ntpd.service'
  20         'ntpdate.service'
  21         'ntp.sysusers')
  22 sha1sums=('e34e5b6f48c3ed1bbcfb03080dec1b8f91e19381'
  23           '1423b8ef72a3806ed74affc1973f66ed7cfa2afb'
  24           'ad1d6ee2e9aca64a84a7224c88bf6008ac6c69e1'
  25           '0cccca872385e0142888ab48d273fec0669b30a8'
  26           '059b382d1af0c55202e2d17f2ae065a2cbfec9ee'
  27           'e8d1c895eabeb45b1a5f096fa5fc3c088eb3ee71')
  28 options=('!emptydirs')
  29
  30 prepare() {
  31         cd "${srcdir}/${_pkgname}-${_pkgver}"
  32         patch -Np1 -i ../ntp-4.2.8_p15-glibc-2.34.patch
  33 }
  34
  35 build() {
  36         cd "${srcdir}/${_pkgname}-${_pkgver}"
  37
  38         ./configure --prefix=/usr --libexecdir=/usr/lib --enable-linuxcaps --enable-ntp-signd
  39         make
  40 }
  41
  42 package() {
  43         cd "${srcdir}/${_pkgname}-${_pkgver}"
  44
  45         make DESTDIR="${pkgdir}" install
  46
  47         install -Dm644 ../ntp.conf "${pkgdir}"/etc/ntp.conf
  48         install -Dm644 ../ntpd.service "${pkgdir}"/usr/lib/systemd/system/ntpd.service
  49         install -Dm644 ../ntpdate.service "${pkgdir}"/usr/lib/systemd/system/ntpdate.service
  50         install -Dm644 ../ntp.sysusers "${pkgdir}"/usr/lib/sysusers.d/ntp.conf
  51         install -Dm644 COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  52
  53         install -d -o 87 "${pkgdir}"/var/lib/ntp
  54         echo > "${pkgdir}/var/lib/ntp/.placeholder"
  55 }