wxpython/trunk/PKGBUILD

   1 # Maintainer: Eric Bélanger <eric@archlinux.org>
   2
   3 pkgname=wxpython
   4 pkgver=3.0.2.0
   5 _editraver=0.7.20
   6 pkgrel=2
   7 pkgdesc="A wxWidgets GUI toolkit for Python"
   8 arch=('x86_64')
   9 license=('custom:wxWindows')
  10 url="http://www.wxpython.org"
  11 depends=('wxgtk' 'python2')
  12 makedepends=('mesa' 'glu')
  13 source=(http://downloads.sourceforge.net/wxpython/wxPython-src-${pkgver}.tar.bz2
  14         http://editra.org/uploads/src/Editra-${_editraver}.tar.gz)
  15 sha256sums=('d54129e5fbea4fb8091c87b2980760b72c22a386cb3b9dd2eebc928ef5e8df61'
  16             'ed515bca58d87d9a2b3085f322a9fe7c6d1407a3b05db1434f80ea8f7e42ccc0')
  17
  18 prepare() {
  19   cd "${srcdir}"
  20   find . -type f -exec sed -i 's/env python/env python2/' {} \;
  21   sed -i 's/sys.exit(1)//' Editra-${_editraver}/setup.py
  22 }
  23
  24 build() {
  25   cd wxPython-src-${pkgver}
  26   ./configure --prefix=/usr --libdir=/usr/lib --with-gtk=2 --with-opengl --enable-unicode \
  27     --enable-graphics_ctx --enable-mediactrl --disable-precomp-headers \
  28     --with-regex=sys --with-libpng=sys --with-libxpm=sys --with-libjpeg=sys --with-libtiff=sys
  29   cd wxPython
  30   python2 setup.py WXPORT=gtk2 UNICODE=1 build
  31 }
  32
  33 package() {
  34   cd wxPython-src-${pkgver}/wxPython
  35   python2 setup.py WXPORT=gtk2 UNICODE=1 install --root="${pkgdir}"
  36   install -D -m644 ../docs/licence.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  37
  38   cd "${srcdir}/Editra-${_editraver}"
  39   python2 setup.py install --root="${pkgdir}"
  40   rm -r "${pkgdir}/usr/lib/python2.7/site-packages/wx-3.0-gtk2/wx/tools/Editra"
  41 }