xterm/trunk/PKGBUILD

   1 # Maintainer:
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Alexander Baldeck <alexander@archlinux.org>
   4
   5 pkgname=xterm
   6 pkgver=379
   7 pkgrel=1
   8 pkgdesc="X Terminal Emulator"
   9 arch=('x86_64')
  10 url="https://invisible-island.net/xterm/"
  11 license=('custom')
  12 depends=('libxft' 'libxaw' 'ncurses' 'luit' 'xbitmaps' 'libutempter' 'libxkbfile')
  13 source=(https://invisible-mirror.net/archives/${pkgname}/${pkgname}-${pkgver}.tgz{,.asc})
  14 sha256sums=('a7ddf274ee84b97fb1283675009d53ca2d02a0ffd5ce5a5118dafc3623ebb310'
  15             'SKIP')
  16 #validpgpkeys=('C52048C0C0748FEE227D47A2702353E0F7E48EDB') # "Thomas Dickey <dickey@invisible-island.net>"
  17 validpgpkeys=('19882D92DDA4C400C22C0D56CC2AF4472167BE03') # "Thomas E. Dickey (self-signed w/o SHA1) <dickey@invisible-island.net>"
  18
  19 build() {
  20   cd ${pkgname}-${pkgver}
  21   ./configure --prefix=/usr \
  22       --libdir=/etc \
  23       --mandir=/usr/share/man \
  24       --with-app-defaults=/usr/share/X11/app-defaults/ \
  25       --with-x \
  26       --disable-full-tgetent \
  27       --disable-imake \
  28       --enable-ansi-color \
  29       --enable-88-color \
  30       --enable-256-color \
  31       --enable-broken-osc \
  32       --enable-broken-st \
  33       --enable-load-vt-fonts \
  34       --enable-i18n \
  35       --enable-wide-chars \
  36       --enable-doublechars \
  37       --enable-warnings \
  38       --enable-tcap-query \
  39       --enable-logging \
  40       --enable-dabbrev \
  41       --enable-freetype \
  42       --enable-luit \
  43       --enable-mini-luit \
  44       --enable-narrowproto \
  45       --enable-exec-xterm \
  46       --enable-sixel-graphics \
  47       --enable-regis-graphics \
  48       --with-tty-group=tty \
  49       --with-utempter
  50   make
  51 }
  52
  53 check() {
  54   cd "$pkgname-$pkgver"
  55   make -k check
  56 }
  57
  58 package() {
  59   cd ${pkgname}-${pkgver}
  60   make DESTDIR="${pkgdir}" install
  61   chmod 0755 "${pkgdir}/usr/bin/xterm"
  62
  63   install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  64   install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
  65   install -m755 -d "${pkgdir}"/usr/share/applications
  66   install -m644 "${srcdir}"/${pkgname}-${pkgver}/{xterm,uxterm}.desktop "${pkgdir}"/usr/share/applications/
  67 }