libcryptui/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=libcryptui
   5 pkgver=3.12.2+r69+g9c70a43b
   6 pkgrel=1
   7 epoch=1
   8 pkgdesc="Library for OpenPGP prompts"
   9 url="https://gitlab.gnome.org/GNOME/libcryptui"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(gtk3 gpgme dbus-glib libnotify gcr dconf libsm)
  13 makedepends=(intltool gobject-introspection gnome-common git)
  14 provides=(libcryptui.so)
  15 options=(debug)
  16 _commit=9c70a43b54c343c056b84cd981e42ce5d6be17b4  # master
  17 source=("git+https://gitlab.gnome.org/GNOME/libcryptui.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27   NOCONFIGURE=1 ./autogen.sh
  28 }
  29
  30 build() {
  31   cd $pkgname
  32   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  33               --disable-static --disable-schemas-compile --enable-gtk-doc
  34   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  35   make
  36 }
  37
  38 package() {
  39   cd $pkgname
  40   make DESTDIR="$pkgdir" install
  41 }