dash/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Dan McGee <dan@archlinux.org>
   3
   4 pkgname=dash
   5 pkgver=0.5.11.5
   6 pkgrel=1
   7 pkgdesc='POSIX compliant shell that aims to be as small as possible'
   8 url='http://gondor.apana.org.au/~herbert/dash/'
   9 arch=('x86_64')
  10 license=('BSD')
  11 depends=('glibc' 'libedit' 'libedit.so')
  12 install=dash.install
  13 options=('debug')
  14 source=(https://git.kernel.org/pub/scm/utils/dash/dash.git/snapshot/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('324e7971bb9ab93246e811600f59a059462abc4fefc48c7d53782b518d560f740ace95f41b5d8c215279c6084c1881ff8bbdaabee69fdae66c971d3e9bdce2d4')
  16 b2sums=('f8ad8eacbb13ea00ecccde33d32ea5cd7527b7fbef5a4e11765925239de91d916184a3b9fff9757629512a76eed3ae5cc46f5cf588fc65bd82616b187cb9cd2e')
  17
  18 prepare() {
  19   cd ${pkgname}-${pkgver}
  20   autoreconf -fiv
  21 }
  22
  23 build() {
  24   cd ${pkgname}-${pkgver}
  25   ./configure \
  26     --prefix=/usr \
  27     --bindir=/usr/bin \
  28     --mandir=/usr/share/man \
  29     --exec-prefix="" \
  30     --with-libedit
  31   make V=1
  32 }
  33
  34 package() {
  35   cd ${pkgname}-${pkgver}
  36   make DESTDIR="${pkgdir}" install
  37   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  38 }