memcached/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Dan McGee <dan@archlinux.org>
   3 # Contributor: Michael Irwin <6d6469@gmail.com>
   4
   5 pkgname=memcached
   6 pkgver=1.6.15
   7 pkgrel=1
   8 pkgdesc='Distributed memory object caching system'
   9 url='https://memcached.org/'
  10 arch=('x86_64')
  11 license=('GPL')
  12 depends=('glibc' 'libevent' 'libseccomp' 'libseccomp.so')
  13 optdepends=('perl: for memcached-tool usage')
  14 source=(https://www.memcached.org/files/${pkgname}-${pkgver}.tar.gz
  15         memcached.service.patch
  16         memcached.tmpfiles
  17         memcached.sysusers)
  18 sha512sums=('00ee15eb7932420a25f3ce973bc7fcc5ba77a514091883f8b4e58ea861073caa91c676c0020f03c768077e20c76f34bca96616be104af3fbc8e7e78303958f3d'
  19             'dd21f49062054c601469f9abc9ee39a0f06c604e8805e7bc9bf2cfa65429962f93e7ac67764257c578fc15b1e75394956f350162c99b084c76a6e14d9331f31f'
  20             '960705ff74d25afed477e0b2a5872a3a4fb49ed3105a351f0d0224abc947778f9dbda81e80be94ab636da4a8411a9dd56a8fd4513e5b86a3096a14fa67f1548b'
  21             'e6ddcab9a6fee024072b6363ef60aa176ed258369bf3a17d475f19b1f410ffd6195b9c5737dc5b1371e8974b44bdbdaa109927acaeb54fb40302a5d67d7c13a8')
  22
  23 prepare() {
  24   cd ${pkgname}-${pkgver}
  25   patch -Np1 < ../memcached.service.patch
  26   sed -e 's/^##safer##//g' -i scripts/*.service
  27 }
  28
  29 build() {
  30   cd ${pkgname}-${pkgver}
  31   ./configure \
  32     --prefix=/usr \
  33     --enable-seccomp
  34   make
  35 }
  36
  37 check() {
  38   cd ${pkgname}-${pkgver}
  39   make test
  40 }
  41
  42 package() {
  43   cd ${pkgname}-${pkgver}
  44   make DESTDIR="${pkgdir}" install
  45
  46   install -Dm 755 scripts/memcached-tool -t "${pkgdir}/usr/bin"
  47   install -Dm 644 scripts/memcached-tool.1 -t "${pkgdir}/usr/share/man/man1"
  48
  49   install -Dm 644 scripts/*.service -t "${pkgdir}/usr/lib/systemd/system"
  50   install -Dm 644 ../memcached.tmpfiles "${pkgdir}/usr/lib/tmpfiles.d/memcached.conf"
  51   install -Dm 644 ../memcached.sysusers "${pkgdir}/usr/lib/sysusers.d/memcached.conf"
  52 }
  53
  54 # vim: ts=2 sw=2 et: