dconf/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=dconf
   5 pkgver=0.40.0
   6 pkgrel=1
   7 pkgdesc="Configuration database system"
   8 url="https://wiki.gnome.org/Projects/dconf"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(glib2)
  12 makedepends=(vala dbus git gtk-doc python meson bash-completion)
  13 provides=(libdconf.so)
  14 install=dconf.install
  15 _commit=4c0a26052efafae923eba42d14c5cb88da745de2  # tags/0.40.0^0
  16 source=("git+https://gitlab.gnome.org/GNOME/dconf.git#commit=$_commit"
  17         dconf-update dconf-update.hook)
  18 sha256sums=('SKIP'
  19             '330142605370f82f4229e8a94b245f911407eb629b50f1497f415c70164a90ec'
  20             '8d02176ff001a13d15a7ac087edd2502725494668933fa2c6e6f9cb21ae24e6b')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29 }
  30
  31 build() {
  32   arch-meson $pkgname build -D gtk_doc=true
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   meson test -C build --print-errorlogs
  38 }
  39
  40 package() {
  41   DESTDIR="$pkgdir" meson install -C build
  42   install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
  43   install -Dt "$pkgdir/usr/share/libalpm/scripts" dconf-update
  44
  45   # Prevent this directory from getting removed when other
  46   # packages which install files there get uninstalled
  47   install -Dm644 /dev/null "$pkgdir/etc/dconf/db/.placeholder"
  48 }
  49
  50 # vim:set sw=2 et: