flatpak/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   4
   5 pkgname=flatpak
   6 pkgver=1.14.0
   7 pkgrel=1
   8 epoch=1
   9 pkgdesc="Linux application sandboxing and distribution framework (formerly xdg-app)"
  10 url="https://flatpak.org"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(dbus glib2 curl polkit libxau ostree json-glib libseccomp libarchive
  14          python bubblewrap appstream xdg-dbus-proxy systemd fuse3 libmalcontent)
  15 makedepends=(gobject-introspection gtk-doc git docbook-xsl xmlto)
  16 checkdepends=(valgrind socat)
  17 provides=(libflatpak.so)
  18 options=(debug)
  19 _commit=488038eed44c7edf334d1e28085975d96ce2bdcc  # tags/1.14.0^0
  20 source=(
  21   "git+https://github.com/flatpak/flatpak#commit=$_commit"
  22   git+https://gitlab.gnome.org/GNOME/libglnx.git
  23   git+https://github.com/projectatomic/bubblewrap
  24   git+https://github.com/flatpak/xdg-dbus-proxy
  25   git+https://gitlab.gnome.org/alexl/variant-schema-compiler.git
  26   https://dl.flathub.org/repo/flathub.flatpakrepo
  27   fusermount3.diff
  28   flatpak-bindir.sh
  29 )
  30 sha256sums=('SKIP'
  31             'SKIP'
  32             'SKIP'
  33             'SKIP'
  34             'SKIP'
  35             '3371dd250e61d9e1633630073fefda153cd4426f72f4afa0c3373ae2e8fea03a'
  36             '23e01650d60222082ffb67a16d3ea033192cc9e6932027cf0ea0c55ea17863af'
  37             '1824cb4eb1cc88702cb2b9f1c55b6dfdf20fca5eab83f6e8e532099281328745')
  38
  39 pkgver() {
  40   cd flatpak
  41   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  42 }
  43
  44 prepare() {
  45   cd flatpak
  46
  47   # Support fuse3
  48   # https://bugs.archlinux.org/task/75623
  49   git apply -3 ../fusermount3.diff
  50
  51   git submodule init
  52   git submodule set-url libglnx "$srcdir/libglnx"
  53   git submodule set-url bubblewrap "$srcdir/bubblewrap"
  54   git submodule set-url dbus-proxy "$srcdir/xdg-dbus-proxy"
  55   git submodule set-url variant-schema-compiler "$srcdir/variant-schema-compiler"
  56   git submodule update
  57
  58   NOCONFIGURE=1 ./autogen.sh
  59 }
  60
  61 build() {
  62   cd flatpak
  63
  64   ./configure \
  65     --prefix=/usr \
  66     --sysconfdir=/etc \
  67     --localstatedir=/var \
  68     --sbindir=/usr/bin \
  69     --libexecdir=/usr/lib \
  70     --disable-static \
  71     --enable-gtk-doc \
  72     --with-system-bubblewrap \
  73     --with-system-dbus-proxy \
  74     --with-dbus-config-dir=/usr/share/dbus-1/system.d
  75
  76   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  77
  78   make
  79 }
  80
  81 check() {
  82   cd flatpak
  83   make -k check
  84 }
  85
  86 package() {
  87   depends+=(xdg-desktop-portal)
  88
  89   make -C flatpak DESTDIR="$pkgdir" install
  90
  91   install -Dt "$pkgdir/etc/profile.d" -m644 flatpak-bindir.sh
  92   install -Dt "$pkgdir/etc/flatpak/remotes.d" flathub.flatpakrepo
  93
  94   # Fixup mode to match polkit
  95   install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
  96 }