geoclue/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: György Balló <ballogy@freestart.hu>
   3
   4 pkgname=geoclue
   5 pkgver=2.6.0
   6 pkgrel=3
   7 pkgdesc="Modular geoinformation service built on the D-Bus messaging system"
   8 arch=(x86_64)
   9 url="https://www.freedesktop.org/wiki/Software/GeoClue/"
  10 license=(LGPL)
  11 depends=(libsoup json-glib libmm-glib avahi)
  12 makedepends=(systemd gobject-introspection git vala meson gtk-doc libnotify)
  13 optdepends=('libnotify: Demo Agent')
  14 provides=("geoclue2=$pkgver-$pkgrel")
  15 conflicts=(geoclue2)
  16 replaces=(geoclue2)
  17 backup=(etc/geoclue/geoclue.conf)
  18 _commit=10998ca3215fb6d21b5a32fdf78bb5feffaf4c0f  # tags/2.6.0^0
  19 source=("git+https://gitlab.freedesktop.org/geoclue/geoclue.git#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 # Mozilla API keys (see https://location.services.mozilla.com/api)
  23 # Note: These are for Arch Linux use ONLY. For your own distribution, please
  24 # get your own set of keys. Feel free to contact heftig@archlinux.org for
  25 # more information.
  26 _mozilla_api_key=e05d56db0a694edc8b5aaebda3f2db6a
  27
  28 pkgver() {
  29   cd geoclue
  30   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  31 }
  32
  33 prepare() {
  34   cd geoclue
  35 }
  36
  37 build() {
  38   arch-meson geoclue build \
  39     -D dbus-srv-user=geoclue \
  40     -D dbus-sys-dir=/usr/share/dbus-1/system.d \
  41     -D mozilla-api-key="$_mozilla_api_key"
  42   meson compile -C build
  43 }
  44
  45 check() {
  46   meson test -C build --print-errorlogs
  47 }
  48
  49 package() {
  50   meson install -C build --destdir "$pkgdir"
  51
  52   echo 'u geoclue - "Geoinformation service" /var/lib/geoclue' |
  53     install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/geoclue.conf"
  54
  55   echo 'd /var/lib/geoclue 0755 geoclue geoclue' |
  56     install -Dm644 /dev/stdin "$pkgdir/usr/lib/tmpfiles.d/geoclue.conf"
  57
  58   # Fixup mode to match polkit
  59   install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
  60 }
  61
  62 # vim:set sw=2 et: