gc/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Daniel Isenmann <daniel [at] archlinux.org>
   2 # Contributor: dorphell <dorphell@gmx.net>
   3
   4 pkgname=gc
   5 pkgver=8.2.2
   6 pkgrel=1
   7 pkgdesc="A garbage collector for C and C++"
   8 arch=('x86_64')
   9 url="https://www.hboehm.info/gc/"
  10 license=('GPL')
  11 depends=('gcc-libs')
  12 source=(https://github.com/ivmai/bdwgc/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  13 sha512sums=('4a7b26789ce22ab72bfaadf3029362c5fe26737df1e856e43db7d9b24ee8acf625e35d596bb3f698f91d6a5ddfb6c45a952a1dbd18d47359569696a544c9c248')
  14
  15 build() {
  16   cd ${pkgname}-${pkgver}
  17   ./configure --prefix=/usr --enable-cplusplus --disable-static
  18   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  19   make
  20 }
  21
  22 check() {
  23   cd ${pkgname}-${pkgver}
  24   make check
  25 }
  26
  27 package() {
  28   cd ${pkgname}-${pkgver}
  29   make DESTDIR="${pkgdir}" install
  30   sed 's|GC_MALLOC 1L|gc 3|g' doc/gc.man |
  31     install -Dm644 /dev/stdin "${pkgdir}/usr/share/man/man3/gc.3"
  32 }