grilo/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=grilo
   4 pkgver=0.3.15
   5 pkgrel=2
   6 pkgdesc="Framework that provides access to various sources of multimedia content"
   7 url="https://wiki.gnome.org/Projects/Grilo"
   8 arch=(x86_64)
   9 license=(LGPL)
  10 depends=(libxml2 libsoup liboauth totem-plparser)
  11 makedepends=(gobject-introspection gtk-doc vala git meson gtk3)
  12 optdepends=('grilo-plugins: Plugins for grilo'
  13             'gtk3: Test UI')
  14 provides=(libgr{ilo,lnet,lpls}-0.3.so)
  15 options=(debug)
  16 _commit=14a4a66d92b78d7db6e872cf09db40fbfb6c470d  # tags/grilo-0.3.15^0
  17 source=("git+https://gitlab.gnome.org/GNOME/grilo.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd grilo
  22   git describe --tags | sed 's/^grilo-//;s/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd grilo
  27 }
  28
  29 build() {
  30   arch-meson grilo build -D soup3=false
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package() {
  39   meson install -C build --destdir "$pkgdir"
  40 }
  41
  42 # vim:set sw=2 sts=-1 et: