xfce4-wavelan-plugin/trunk/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: AndyRTR <andyrtr@archlinux.org>
   3 # Contributor: Tobias Kieslich <tobias (at) archlinux.org>
   4
   5 pkgname=xfce4-wavelan-plugin
   6 pkgver=0.6.3
   7 pkgrel=1
   8 pkgdesc="Plugin to monitor wifi connectivity for the Xfce4 panel"
   9 arch=('x86_64')
  10 url="https://docs.xfce.org/panel-plugins/xfce4-wavelan-plugin"
  11 license=('custom')
  12 groups=('xfce4-goodies')
  13 depends=('xfce4-panel')
  14 makedepends=('intltool')
  15 source=(https://archive.xfce.org/src/panel-plugins/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
  16 sha256sums=('61c0c2f56cb70872d403b770dd76349df9ff24c0dbe905ee1b4f913c34d8f72b')
  17
  18 build() {
  19   cd "$srcdir/$pkgname-$pkgver"
  20
  21   ./configure \
  22     --prefix=/usr \
  23     --sysconfdir=/etc \
  24     --libexecdir=/usr/lib \
  25     --localstatedir=/var \
  26     --disable-static \
  27     --disable-debug
  28   make
  29 }
  30
  31 package() {
  32   cd "$srcdir/$pkgname-$pkgver"
  33   make DESTDIR="$pkgdir" install
  34   install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  35 }
  36
  37 # vim:set ts=2 sw=2 et: