irqbalance/repos/community-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Dan McGee <dan@archlinux.org>
   3 # Contributor: Martin Striz <ms@poruba.net>
   4
   5 pkgname=irqbalance
   6 pkgver=1.7.0
   7 pkgrel=1
   8 pkgdesc="IRQ balancing daemon for SMP systems"
   9 arch=('x86_64')
  10 url="https://github.com/irqbalance/irqbalance"
  11 license=('GPL2')
  12 backup=('etc/irqbalance.env')
  13 depends=('glibc' 'libcap-ng')
  14 makedepends=('glib2' 'ncurses' 'numactl' 'systemd' 'systemd-libs')
  15 source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v$pkgver.tar.gz")
  16 sha512sums=('2fa29c738275dda2fac38d78ca0ec4619826b72529e8eda7ad8ddcda5768bbf282e2260dddc16a8b46d4296289b25dc59684575ae1badca0c6c6ae30b1e9b5ea')
  17 b2sums=('1213b21c7d3979c9ba7d2298c21f7f0b75217d251ecfa02660ea0602a032d62c9c9b0254bf158e07e0fdcf55b35f332f5a17f929c7393dfdb894ca952dad52b4')
  18
  19 prepare() {
  20   cd "$pkgname-$pkgver"
  21   # fix location of configuration and binary in service
  22   sed -e 's|/path/to/|/etc/|g' \
  23       -e 's|/usr/sbin|/usr/bin|g' \
  24       -i "misc/${pkgname}.service"
  25   autoreconf -vfi
  26 }
  27
  28 build() {
  29   cd "$pkgname-$pkgver"
  30   ./configure --prefix=/usr \
  31               --sbindir=/usr/bin \
  32               --with-systemd
  33   make
  34 }
  35
  36 package() {
  37   depends+=('libglib-2.0.so' 'libncursesw.so' 'libnuma.so' 'libsystemd.so')
  38   cd "$pkgname-$pkgver"
  39   make install DESTDIR="$pkgdir"
  40   install -vDm 644 misc/irqbalance.service \
  41     -t "${pkgdir}/usr/lib/systemd/system/"
  42   install -vDm 644 misc/irqbalance.env -t "${pkgdir}/etc/"
  43   install -vDm 644 {AUTHORS,README.md} -t "${pkgdir}/usr/share/doc/${pkgname}"
  44 }