onetbb/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Stéphane Gaudreault <stephane@archlinux.org>
   4 # Contributor: Thomas Dziedzic < gostrc at gmail >
   5 # Contributor: Denis Martinez <deuns.martinez AT gmail.com>
   6 # Contributor: Bogdan Burlacu <bogdan.burlacu AT pm.me>
   7
   8 pkgname=onetbb
   9 pkgver=2021.8.0
  10 pkgrel=3
  11 pkgdesc='High level abstract threading library (oneAPI Threading Building Blocks)'
  12 arch=('x86_64')
  13 url='https://oneapi-src.github.io/oneTBB/'
  14 license=('Apache')
  15 depends=('gcc-libs' 'hwloc')
  16 makedepends=('cmake' 'inetutils' 'ninja' 'python' 'swig')
  17 conflicts=('intel-tbb' 'tbb')
  18 provides=("intel-tbb=$pkgver" "tbb=$pkgver")
  19 replaces=('intel-tbb' 'tbb')
  20 source=(https://github.com/oneapi-src/oneTBB/archive/v$pkgver/$pkgname-$pkgver.tar.gz
  21         retry-pthread_create.patch::https://github.com/oneapi-src/oneTBB/pull/824.patch)
  22 sha512sums=('72f68730dfd89409796f9548d3c302111787712089688a7c77092ed1b3a7bf4e7444fe4b58015d2c78b7b71259852526789b2483bf1e71bea8146c4b4676e7b4'
  23             '717d3f78b29ce9e2104cbf962b4ced8a4414dcb8af7259ba12dd62adbacfd59e064ae1771c217cbac46d691ab6bfd52aee90113a5aeb9a1f91379295d16e639a')
  24
  25 prepare() {
  26   cd oneTBB-$pkgver
  27   # FS#77894
  28   patch -p1 -i ../retry-pthread_create.patch
  29 }
  30
  31 build() {
  32   cd oneTBB-$pkgver
  33   cmake -G Ninja -D CMAKE_INSTALL_PREFIX=/usr -D TBB_STRICT=OFF -D TBB4PY_BUILD=ON .
  34   ninja all python_build
  35 }
  36
  37 check() {
  38   cd oneTBB-$pkgver
  39   ninja test
  40 }
  41
  42 package() {
  43   cd oneTBB-$pkgver
  44   DESTDIR="$pkgdir" ninja install
  45 }