harfbuzz/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=harfbuzz
   5 pkgname=(harfbuzz harfbuzz-icu)
   6 pkgver=3.1.2
   7 pkgrel=1
   8 pkgdesc="OpenType text shaping engine"
   9 url="https://www.freedesktop.org/wiki/Software/HarfBuzz"
  10 arch=(x86_64)
  11 license=(MIT)
  12 makedepends=(glib2 freetype2 graphite cairo icu gobject-introspection gtk-doc
  13              ragel git python meson chafa)
  14 checkdepends=(python-fonttools python-setuptools)
  15 _commit=8aed5c21a31eece6a9f3cd775fda8facb6c28b9b  # tags/3.1.2^0
  16 source=("git+https://github.com/harfbuzz/harfbuzz#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd harfbuzz
  21   git describe --tags | sed 's/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd harfbuzz
  26 }
  27
  28 build() {
  29   arch-meson harfbuzz build \
  30     -D graphite2=enabled
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   mkdir -p tmp
  36   TMPDIR="$PWD/tmp" meson test -C build --print-errorlogs
  37   rm -r tmp
  38 }
  39
  40 _pick() {
  41   local p="$1" f d; shift
  42   for f; do
  43     d="$srcdir/$p/${f#$pkgdir/}"
  44     mkdir -p "$(dirname "$d")"
  45     mv "$f" "$d"
  46     rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  47   done
  48 }
  49
  50 package_harfbuzz() {
  51   depends=(glib2 freetype2 graphite libglib-2.0.so libfreetype.so
  52            libgobject-2.0.so)
  53   provides=(libharfbuzz.so libharfbuzz-subset.so libharfbuzz-gobject.so)
  54   optdepends=('cairo: hb-view program'
  55               'chafa: hb-view program')
  56
  57   meson install -C build --destdir "$pkgdir"
  58
  59   ( cd "$pkgdir"
  60
  61     _pick hb-icu usr/lib/libharfbuzz-icu*
  62     _pick hb-icu usr/lib/pkgconfig/harfbuzz-icu.pc
  63     _pick hb-icu usr/include/harfbuzz/hb-icu.h
  64   )
  65
  66   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
  67 }
  68
  69 package_harfbuzz-icu() {
  70   pkgdesc+=" - ICU integration"
  71   depends=("harfbuzz=$pkgver-$pkgrel" libicuuc.so libharfbuzz.so)
  72   provides=(libharfbuzz-icu.so)
  73
  74   mv hb-icu/* "$pkgdir"
  75
  76   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
  77 }