libseccomp/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Tobias Powalowski <tpowa@archlinux.org>
   3 # Contributor: Daniel Micay <danielmicay@gmail.com>
   4 # Contributor: Patryk Kowalczyk < patryk at kowalczyk dot ws>
   5
   6 pkgbase=libseccomp
   7 pkgname=(libseccomp python-libseccomp)
   8 pkgver=2.5.3
   9 pkgrel=3
  10 pkgdesc='Enhanced seccomp library'
  11 arch=('x86_64')
  12 license=('LGPL2.1')
  13 url="https://github.com/seccomp/libseccomp"
  14 depends=('glibc')
  15 checkdepends=('valgrind')
  16 makedepends=('gperf' 'cython' 'python-setuptools')
  17 source=(https://github.com/seccomp/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz{,.asc})
  18 sha256sums=('59065c8733364725e9721ba48c3a99bbc52af921daf48df4b1e012fbc7b10a76'
  19             'SKIP')
  20 b2sums=('cedf04b3a926f9fe5202e6169ddac6b983e755009c14fc1d645157b9c0bcdf65d4085f8ea7abad90f3a0c13ae4d66b5d8306e725168490863aad15976de1eae7'
  21         'SKIP')
  22 validpgpkeys=(
  23   '7100AADFAE6E6E940D2E0AD655E45A5AE8CA7C8A' # Paul Moore <paul@paul-moore.com>
  24   '47A68FCE37C7D7024FD65E11356CE62C2B524099' # Tom Hromatka <tom.hromatka@oracle.com>
  25 )
  26
  27 prepare() {
  28   cd ${pkgbase}-${pkgver}
  29   autoreconf -fiv
  30 }
  31
  32 build() {
  33   cd ${pkgbase}-${pkgver}
  34   ./configure --prefix=/usr
  35   make
  36   cd src/python
  37   env VERSION_RELEASE=${pkgver} python setup.py build
  38 }
  39
  40 check() {
  41   cd ${pkgbase}-${pkgver}
  42   make check
  43 }
  44
  45 package_libseccomp() {
  46   provides=('libseccomp.so')
  47   cd ${pkgbase}-${pkgver}
  48   make DESTDIR="${pkgdir}" install
  49   install -Dm 644 CHANGELOG README.md SECURITY.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  50 }
  51
  52 package_python-libseccomp() {
  53   depends=('python' 'libseccomp.so')
  54   cd ${pkgbase}-${pkgver}/src/python
  55   env VERSION_RELEASE=${pkgver} python setup.py install --root="${pkgdir}" --prefix=/usr -O1 --skip-build
  56 }
  57
  58 # vim: ts=2 sw=2 et: