lirc/repos/testing-x86_64/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Contributor: Paul Mattal <paul@archlinux.org>
   3
   4 pkgname=lirc
   5 _pkgver=0.10.1
   6 [[ $_pkgver =~ [a-z]$ ]] && pkgver="${_pkgver:0:-1}.${_pkgver: -1}" || pkgver="$_pkgver"
   7 pkgrel=10
   8 epoch=1
   9 pkgdesc="Linux Infrared Remote Control utilities"
  10 arch=('x86_64')
  11 url="https://www.lirc.org/"
  12 license=('GPL')
  13 depends=('alsa-lib' 'libx11' 'libftdi' 'libusb-compat')
  14 makedepends=('help2man' 'alsa-lib' 'libx11' 'libxslt' 'python' 'python-setuptools'
  15              'systemd')
  16 optdepends=('python: for lirc-setup, irdb-get and pronto2lirc')
  17 provides=('lirc-utils')
  18 conflicts=('lirc-utils')
  19 replaces=('lirc-utils')
  20 backup=('etc/lirc/lirc_options.conf' 'etc/lirc/lircd.conf' 'etc/lirc/lircmd.conf')
  21 source=("https://prdownloads.sourceforge.net/${pkgname}/${pkgname}-${_pkgver}.tar.bz2"
  22         lirc-0.10-build-fix.patch
  23         lirc.logrotate
  24         lirc.tmpfiles)
  25 sha1sums=('9d6f6d18ac566a96ef4ca1d6909a4e8bc517d48a'
  26           '952ce902c94d822b0113d8e74bc6fda6a551ad7e'
  27           '4342b004eb53d51fcbb9af2cf136bb4990874608'
  28           '5cd3f206e6e60632d9bea2ce9d22dbe5283eb129')
  29
  30 prepare() {
  31   cd "${srcdir}/lirc-${_pkgver}"
  32
  33   patch -p1 -i ../lirc-0.10-build-fix.patch
  34
  35   autoreconf -fi
  36   automake -ac
  37 }
  38
  39 build() {
  40   cd "${srcdir}/lirc-${_pkgver}"
  41
  42   HAVE_UINPUT=1 ./configure --prefix=/usr --sbindir=/usr/bin --sysconfdir=/etc --localstatedir=/var
  43   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  44   make
  45 }
  46
  47 package() {
  48   cd "${srcdir}/lirc-${_pkgver}"
  49
  50   make DESTDIR="${pkgdir}" -j1 install
  51
  52   install -Dm644 "${srcdir}"/lirc.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/lirc.conf
  53   install -Dm644 "${srcdir}"/lirc.logrotate "${pkgdir}"/etc/logrotate.d/lirc
  54
  55   rmdir "${pkgdir}"/var/{run/lirc/,run/}
  56 }