vala/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4 # Contributor: Timm Preetz <timm@preetz.us>
   5
   6 pkgname=vala
   7 pkgver=0.54.4
   8 pkgrel=1
   9 pkgdesc='Compiler for the GObject type system'
  10 url='https://wiki.gnome.org/Projects/Vala'
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(glib2 gtk-doc graphviz ttf-font pkg-config gcc)
  14 makedepends=(libxslt vala git help2man autoconf-archive)
  15 checkdepends=(dbus libx11 gobject-introspection)
  16 provides=(valadoc libvala-${pkgver%.*}.so libvaladoc-${pkgver%.*}.so)
  17 conflicts=(valadoc)
  18 replaces=(valadoc)
  19 _commit=c922bdce3df8d4aa3afd488b584b70d614cc8ba4  # tags/0.54.4^0
  20 source=("git+https://gitlab.gnome.org/GNOME/vala.git#commit=$_commit")
  21 sha256sums=('SKIP')
  22
  23 pkgver() {
  24   cd $pkgname
  25   git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  26 }
  27
  28 prepare() {
  29   cd $pkgname
  30   NOCONFIGURE=1 ./autogen.sh
  31 }
  32
  33 build() {
  34   cd $pkgname
  35   ./configure --prefix=/usr
  36   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  37   make
  38 }
  39
  40 check() {
  41   cd $pkgname
  42   make check
  43 }
  44
  45 package() {
  46   cd $pkgname
  47   make DESTDIR="$pkgdir" install
  48 }
  49
  50 # vim: ts=2 sw=2 et: