doxygen/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Dan McGee <dan@archlinux.org>
   3
   4 pkgbase=doxygen
   5 pkgname=('doxygen' 'doxygen-docs')
   6 pkgver=1.9.3
   7 pkgrel=1
   8 pkgdesc='Documentation system for C++, C, Java, IDL and PHP'
   9 url='http://www.doxygen.nl'
  10 arch=('x86_64')
  11 license=('GPL')
  12 makedepends=('cmake' 'gcc-libs' 'flex' 'qt5-base' 'texlive-core' 'ghostscript'
  13              'texlive-latexextra' 'graphviz' 'python' 'git')
  14 source=(${pkgbase}-${pkgver}.tar.gz::https://github.com/doxygen/doxygen/archive/Release_${pkgver//./_}.tar.gz)
  15 sha256sums=('c29426222c9361dc33b762cf1c6447c78cfb0b9c213e5dcdbe31a10540c918c5')
  16 sha512sums=('8fcec24d7f92c0d01444cb4b64a39adbe3467b7d75bf191ab667190d4feb1c99ac796fc5b1be6ae5f386321e3d85f28d4cbee05041f048f32ef68ea773d74ff9')
  17 b2sums=('81451704cdf1676db58ad7706c06bc5587f8fdcd8e10b17d0909c1a288c6d92d6080334544b7c7ae88e1fe459511e9f2da8781672e9856c03e4c553f5c1f1e49')
  18
  19 prepare() {
  20   cd ${pkgbase}-Release_${pkgver//./_}
  21   # Install the man pages in the right place
  22   sed -i 's:DESTINATION man/man1:DESTINATION "${CMAKE_INSTALL_PREFIX}/share/man/man1":g' \
  23     doc/CMakeLists.txt
  24 }
  25
  26 build() {
  27   cd ${pkgbase}-Release_${pkgver//./_}
  28
  29   cmake -B build \
  30     -DCMAKE_INSTALL_PREFIX:PATH=/usr \
  31     -DDOC_INSTALL_DIR:PATH=share/doc/doxygen \
  32     -DPYTHON_EXECUTABLE:FILE=/usr/bin/python \
  33     -Dbuild_doc:BOOL=ON \
  34     -Dbuild_wizard:BOOL=ON
  35   make -C build
  36   make -C build docs -j1
  37 }
  38
  39 check() {
  40   cd ${pkgbase}-Release_${pkgver//./_}
  41   make -C build tests
  42 }
  43
  44 package_doxygen() {
  45   pkgdesc='Documentation system for C++, C, Java, IDL and PHP'
  46   depends=('gcc-libs')
  47   optdepends=('graphviz: for caller/callee graph generation'
  48               'qt5-base: for doxywizard')
  49
  50   cd ${pkgbase}-Release_${pkgver//./_}
  51   make -C build DESTDIR="${pkgdir}" install
  52
  53   rm -rf "${pkgdir}/usr/share/doc"
  54 }
  55
  56 package_doxygen-docs() {
  57   pkgdesc='Developer documentation for doxygen'
  58
  59   cd ${pkgbase}-Release_${pkgver//./_}
  60   make -C build DESTDIR="${pkgdir}" install
  61
  62   rm -rf "${pkgdir}/usr/bin"
  63   rm -rf "${pkgdir}/usr/share/man"
  64 }
  65
  66 # vim: ts=2 sw=2 et: