gnome-nettool/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Kritoke <kritoke@nospam.gmail.com>
   4
   5 pkgname=gnome-nettool
   6 pkgver=42.0
   7 pkgrel=1
   8 pkgdesc="Graphical interface for various networking tools"
   9 url="https://gitlab.gnome.org/GNOME/gnome-nettool"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(gtk3 libgtop iputils whois)
  13 makedepends=(nmap bind net-tools git meson yelp-tools)
  14 optdepends=('nmap: Port scanning'
  15             'bind: DNS lookup'
  16             'net-tools: Network statistics')
  17 groups=(gnome-extra)
  18 options=(debug)
  19 _commit=5748c0fa632c9caad9e46377ca1aa330dec4b757  # tags/gnome-nettool-42-0^0
  20 source=("git+https://gitlab.gnome.org/GNOME/gnome-nettool.git#commit=$_commit"
  21         fix-build.diff)
  22 sha256sums=('SKIP'
  23             '95437116039a453c7c15eb25b90e3818338d6b6a87437f384b3d6aded4a845d7')
  24
  25 pkgver() {
  26   cd $pkgname
  27   git describe --tags | sed 's/^gnome-nettool-//;s/-/./;s/[^-]*-g/r&/;s/-/+/g'
  28 }
  29
  30 prepare() {
  31   cd $pkgname
  32
  33   # Fix build with recent Meson
  34   git apply -3 ../fix-build.diff
  35 }
  36
  37 build() {
  38   arch-meson $pkgname build
  39   meson compile -C build
  40 }
  41
  42 check() {
  43   meson test -C build --print-errorlogs
  44 }
  45
  46 package() {
  47   meson install -C build --destdir "$pkgdir"
  48 }