libmicrohttpd/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
   2 # Maintainer: Norberto Lopes <shelika@mail.telepac.pt>
   3 # Contributor: Kao Dome <kaodome@gmail.com>
   4 # Contributor: Dmitrij D. Czarkoff <czarkoff@gmail.com>
   5 # Contributor: Mathias Rohnstock <linksoft@gmx.de>
   6
   7 pkgname=libmicrohttpd
   8 pkgver=0.9.75
   9 pkgrel=1
  10 pkgdesc='a small C library that is supposed to make it easy to run an HTTP server as part of another application.'
  11 arch=('x86_64')
  12 url='https://www.gnu.org/software/libmicrohttpd/'
  13 license=('LGPL')
  14 depends=('gnutls')
  15 checkdepends=('curl')
  16 provides=('libmicrohttpd.so')
  17 validpgpkeys=('EA812DBEFA5A7EF17DA8F2C1460A317C3326D2AE'  # Evgeny Grin (Karlson2k) <k2k@yandex.ru>
  18               'D8423BCB326C7907033929C7939E6BE1E29FC3CC') # Christian Grothoff <christian.grothoff@bfh.ch>
  19 source=("https://ftp.gnu.org/gnu/libmicrohttpd/$pkgname-$pkgver.tar.gz"{,.sig})
  20 sha256sums=('9278907a6f571b391aab9644fd646a5108ed97311ec66f6359cebbedb0a4e3bb'
  21             'SKIP')
  22
  23 build() {
  24   cd ${pkgname}-${pkgver}
  25
  26   ./configure \
  27     --prefix=/usr \
  28     --disable-dependency-tracking \
  29     --disable-examples \
  30     --enable-curl \
  31     --enable-https \
  32     --enable-largefile \
  33     --enable-messages \
  34     --with-pic
  35   make
  36 }
  37
  38 check() {
  39   cd ${pkgname}-${pkgver}
  40
  41   make check
  42 }
  43
  44 package() {
  45   cd ${pkgname}-${pkgver}
  46
  47   make DESTDIR="$pkgdir" install
  48 }