lz4/trunk/PKGBUILD

   1 # Maintainer: Sébastien Luttringer
   2
   3 pkgname=lz4
   4 epoch=1
   5 pkgver=1.9.3
   6 pkgrel=2
   7 pkgdesc='Extremely fast compression algorithm'
   8 arch=('x86_64')
   9 url='http://www.lz4.org/'
  10 license=('GPL2')
  11 makedepends=('git')
  12 checkdepends=('diffutils')
  13 depends=('glibc')
  14 source=("git+https://github.com/lz4/lz4.git#tag=v$pkgver"
  15         'https://github.com/lz4/lz4/commit/8301a21773ef61656225e264f4f06ae14462bca7.patch')
  16 sha256sums=('SKIP'
  17             'c99da650a79a42db4db23e72146701cce9106383ba45709c5ac89022e36dcfb2')
  18
  19 prepare() {
  20   cd $pkgname
  21   # apply patch from the source array (should be a pacman feature)
  22   local src
  23   for src in "${source[@]}"; do
  24     src="${src%%::*}"
  25     src="${src##*/}"
  26     [[ $src = *.patch ]] || continue
  27     msg2 "Applying patch $src..."
  28     patch -Np1 < "../$src"
  29   done
  30 }
  31
  32 build() {
  33   # do not use the main makefile, it calls sub make with -e
  34   # exported CLFAGS by makepkg break the version. see FS#50071
  35   cd $pkgname
  36   make -C lib PREFIX=/usr
  37   make -C programs PREFIX=/usr lz4 lz4c
  38 }
  39
  40 check() {
  41   rm -f passwd.lz4
  42   $pkgname/programs/lz4 /etc/passwd passwd.lz4
  43   $pkgname/programs/lz4 -d passwd.lz4 passwd
  44   diff -q /etc/passwd passwd
  45   rm passwd
  46 }
  47
  48 package() {
  49   cd $pkgname
  50   make install PREFIX=/usr DESTDIR="$pkgdir"
  51 }
  52
  53 # vim:set ts=2 sw=2 et: