python-appdirs/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Tobias Roettger <toroettg@gmail.com>
   3
   4 pkgbase=python-appdirs
   5 pkgname=(python-appdirs python2-appdirs)
   6 pkgver=1.4.4
   7 pkgrel=6
   8 pkgdesc='A small Python module for determining appropriate platform-specific dirs, e.g. a "user data dir".'
   9 arch=('any')
  10 url="https://github.com/ActiveState/appdirs"
  11 license=('MIT')
  12 makedepends=('python-setuptools' 'python2-setuptools')
  13 source=("https://pypi.io/packages/source/a/appdirs/appdirs-$pkgver.tar.gz")
  14 sha512sums=('8b0cdd9fd471d45b186aa47607691cf378dabd3edc7b7026a57bd6d6f57698e86f440818a5e23ba4288b35d6bb8cb6eb0106eae8aab09d8863ee15025d300883')
  15
  16 prepare() {
  17   cp -a appdirs-$pkgver{,-py2}
  18 }
  19
  20 build() {
  21   cd "$srcdir"/appdirs-$pkgver
  22   python setup.py build
  23
  24   cd "$srcdir"/appdirs-$pkgver-py2
  25   python2 setup.py build
  26 }
  27
  28 check() {
  29   cd "$srcdir"/appdirs-$pkgver
  30   python setup.py test
  31
  32   cd "$srcdir"/appdirs-$pkgver-py2
  33   python2 setup.py test
  34 }
  35
  36 package_python-appdirs() {
  37   depends=('python')
  38
  39   cd appdirs-$pkgver
  40   python setup.py install --root="$pkgdir/" --optimize=1
  41   install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
  42 }
  43
  44 package_python2-appdirs() {
  45   depends=('python2')
  46
  47   cd appdirs-$pkgver-py2
  48   python2 setup.py install --root="$pkgdir/" --optimize=1
  49   install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
  50 }
  51
  52 # vim:set ts=2 sw=2 et: