cogl/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=cogl
   5 pkgver=1.22.8
   6 pkgrel=2
   7 pkgdesc="An object oriented GL/GLES Abstraction/Utility Layer"
   8 url="https://blogs.gnome.org/clutter/"
   9 arch=(x86_64)
  10 license=(GPL2)
  11 depends=(mesa libdrm libxext libxdamage libxcomposite gdk-pixbuf2 pango
  12          libxrandr)
  13 makedepends=(gobject-introspection git gtk-doc)
  14 provides=(libcogl.so libcogl-{gles2,pango,path}.so)
  15 options=(debug)
  16 _commit=c2e25cef6bd7b3f12c8625f82956388e419cd046  # tags/1.22.8^0
  17 source=("git+https://gitlab.gnome.org/GNOME/cogl.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd cogl
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd cogl
  27   NOCONFIGURE=1 ./autogen.sh
  28 }
  29
  30 build() {
  31   cd cogl
  32   ./configure --prefix=/usr \
  33     --enable-gles2 \
  34     --enable-{kms,wayland}-egl-platform \
  35     --enable-wayland-egl-server
  36
  37   # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  38   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  39
  40   make
  41 }
  42
  43 package() {
  44   cd cogl
  45   make DESTDIR="$pkgdir" install
  46 }
  47
  48 # vim:set sw=2 et: