libmtp/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Tom Gundersen <teg@jklm.no>
   3 # Contributor: damir <damir@archlinux.org>
   4 # Contributor: Kevin Edmonds <edmondskevin@hotmail.com>
   5
   6 pkgname=libmtp
   7 pkgver=1.1.20
   8 pkgrel=1
   9 pkgdesc='Library implementation of the Media Transfer Protocol'
  10 arch=(x86_64)
  11 url='http://libmtp.sourceforge.net'
  12 license=(LGPL)
  13 depends=(libusb)
  14 makedepends=(doxygen)
  15 source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz{,.asc})
  16 sha256sums=('c9191dac2f5744cf402e08641610b271f73ac21a3c802734ec2cedb2c6bc56d0'
  17             'SKIP')
  18 validpgpkeys=(7C4AFD61D8AAE7570796A5172209D6902F969C95) # Marcus Meißner <meissner@suse.de>
  19
  20 build() {
  21   cd $pkgname-$pkgver
  22   ./configure --prefix=/usr --with-udev=/usr/lib/udev
  23   make
  24 }
  25
  26 check() {
  27   cd $pkgname-$pkgver
  28   make -k check
  29 }
  30
  31 package() {
  32   cd $pkgname-$pkgver
  33   make DESTDIR="$pkgdir" install
  34
  35 # Install man page
  36   install -Dm644 doc/man/man3/*.3 -t "$pkgdir"/usr/share/man/man3/
  37 }