lmdb/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Matt Monaco <cx monaco matt>
   3
   4 pkgname=lmdb
   5 pkgver=0.9.30
   6 _commit=8f44dca45d87bc1f8da65428172668c5e6154179
   7 pkgrel=3
   8 pkgdesc="Symas Lightning Memory-Mapped Database"
   9 arch=('x86_64')
  10 url="https://symas.com/lmdb"
  11 license=('custom:OpenLDAP')
  12 depends=('glibc')
  13 makedepends=('git')
  14 options=('!emptydirs')
  15 source=("git+https://git.openldap.org/openldap/openldap.git#commit=$_commit"
  16         lmdb.pc)
  17 sha512sums=('SKIP'
  18             '0349d4b08a1f93fe338d8f8e3e5a83e24211a46f999fe529bc1ac49c8c4975559d95a548c203d9427e3f82d62e934ba3cd1be6f734f9b9405b2a26477be4ed33')
  19
  20 prepare() {
  21   sed -e "s|@PKGVER@|$pkgver|" -i lmdb.pc
  22 }
  23
  24 build() {
  25   cd openldap/libraries/liblmdb
  26   make CFLAGS="$CFLAGS" CPPFLAGS="$CPPFLAGS" LDFLAGS="$LDFLAGS" prefix=/usr
  27 }
  28
  29 check() {
  30   cd openldap/libraries/liblmdb
  31   make test
  32 }
  33
  34 package() {
  35   cd openldap/libraries/liblmdb
  36   install -dm755 "$pkgdir"/usr/{bin,lib,include,man/man1,share}
  37   make DESTDIR="$pkgdir" prefix=/usr install
  38
  39   mv "$pkgdir"/usr/man "$pkgdir"/usr/share/man
  40
  41   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  42   install -Dm644 "$srcdir"/lmdb.pc -t "$pkgdir"/usr/lib/pkgconfig/
  43 }