asio/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: Aaron Griffin <aaron@archlinux.org>
   4
   5 pkgname=asio
   6 pkgver=1.28.0
   7 pkgrel=1
   8 pkgdesc='Cross-platform C++ library for ASynchronous network I/O'
   9 url='https://think-async.com/Asio/'
  10 arch=('any')
  11 license=('custom:boost')
  12 makedepends=('boost')
  13 source=(https://sourceforge.net/projects/asio/files/asio/${pkgver}%20%28Stable%29/asio-${pkgver}.tar.bz2)
  14 sha512sums=('b3fa23caa4cbf1e374fade97102adb22a32c68bd4b050474987c065b516fdf042d46842c41ac94e71458f402fae2d05bc8f617ee523ffb6a74ef33d214e9acd5')
  15 b2sums=('dc0431a6710f58ce037d6e6e1cf81606b6f8be3ac9fdf6f7a69a7998fadb4f3c9dace2aa99606a9570166f9637ca7f4b9ab6964599c78027a9f32a9d243d5684')
  16
  17 prepare() {
  18   cd ${pkgname}-${pkgver}
  19   autoreconf -fiv
  20 }
  21
  22 build() {
  23   cd ${pkgname}-${pkgver}
  24   ./configure \
  25     --prefix=/usr
  26   make
  27 }
  28
  29 check() {
  30   cd ${pkgname}-${pkgver}
  31   make check
  32 }
  33
  34 package() {
  35   cd ${pkgname}-${pkgver}
  36   make DESTDIR="${pkgdir}" install
  37   install -Dm 644 COPYING LICENSE_1_0.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  38 }
  39
  40 # vim: ts=2 sw=2 et: