gdk-pixbuf2/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=gdk-pixbuf2
   5 pkgname=(gdk-pixbuf2 gdk-pixbuf2-docs)
   6 pkgver=2.42.10
   7 pkgrel=2
   8 pkgdesc="An image loading library"
   9 url="https://wiki.gnome.org/Projects/GdkPixbuf"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(glib2 libpng libtiff libjpeg shared-mime-info)
  13 makedepends=(gobject-introspection git meson gi-docgen python-docutils)
  14 optdepends=(
  15   "libwmf: Load .wmf and .apm"
  16   "libopenraw: Load .dng, .cr2, .crw, .nef, .orf, .pef, .arw, .erf, .mrw, and .raf"
  17   "libavif: Load .avif"
  18   "libheif: Load .heif, .heic, and .avif"
  19   "libjxl: Load .jxl"
  20   "librsvg: Load .svg, .svgz, and .svg.gz"
  21   "webp-pixbuf-loader: Load .webp"
  22 )
  23 _commit=9ac257eb38f772fec4253e8051743029e75a2acd  # tags/2.42.10^0
  24 source=(
  25   "git+https://gitlab.gnome.org/GNOME/gdk-pixbuf.git#commit=$_commit"
  26   gdk-pixbuf-query-loaders.hook
  27 )
  28 sha256sums=('SKIP'
  29             '9fb71d95e6a212779eb0f88dde5a3cee0df7f4d9183f8f9ce286f8cdc14428f0')
  30
  31 pkgver() {
  32   cd gdk-pixbuf
  33   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  34 }
  35
  36 prepare() {
  37   cd gdk-pixbuf
  38 }
  39
  40 build() {
  41   arch-meson gdk-pixbuf build \
  42     -D builtin_loaders=all \
  43     -D gtk_doc=true \
  44     -D installed_tests=false
  45   meson compile -C build
  46 }
  47
  48 check() {
  49   meson test -C build --print-errorlogs
  50 }
  51
  52 package_gdk-pixbuf2() {
  53   provides=(libgdk_pixbuf-2.0.so)
  54   install=gdk-pixbuf2.install
  55
  56   meson install -C build --destdir "$pkgdir"
  57
  58   mkdir -p doc/usr/share
  59   mv {"$pkgdir",doc}/usr/share/doc
  60
  61   install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
  62 }
  63
  64 package_gdk-pixbuf2-docs() {
  65   pkgdesc+=" (documentation)"
  66   depends=()
  67
  68   mv doc/* "$pkgdir"
  69 }
  70
  71 # vim:set sw=2 sts=-1 et: