mesa-demos/trunk/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2
   3 pkgbase=mesa-demos
   4 pkgname=('mesa-demos' 'mesa-utils')
   5 pkgver=9.0.0
   6 pkgrel=2
   7 arch=('x86_64')
   8 url="https://www.mesa3d.org/"
   9 license=('custom')
  10 #makedepends=('meson' 'mesa' 'glu' 'freeglut' 'wayland-protocols')
  11 makedepends=('meson' 'mesa' 'libxkbcommon-x11'
  12              'libdecor' 'glu' 'freeglut'
  13              'glslang' 'vulkan-headers' 'wayland-protocols')
  14 source=(https://mesa.freedesktop.org/archive/demos/mesa-demos-${pkgver}.tar.xz{,.sig}
  15         'LICENSE')
  16 sha512sums=('af33ef72a521416e39d93370b2b4ccb768f08084c9e4c0aa62868210d9465c858e5cb8e5d23952295a3073946f609eb8723ee60b39dd9fb6696c4e45aafbb2c1'
  17             'SKIP'
  18             '25da77914dded10c1f432ebcbf29941124138824ceecaf1367b3deedafaecabc082d463abcfa3d15abff59f177491472b505bcb5ba0c4a51bb6b93b4721a23c2')
  19 #validpgpkeys=('E390B9700582FAEA959ACAD41EEF53D38A3A9C67') # "Andreas Boll <andreas.boll.dev@gmail.com>"
  20 validpgpkeys=('FF4CF638C624C3CF21ED2CF227EF763A2AA39F96') # Erik Faye-Lund <erik.faye-lund@collabora.com>
  21
  22 build() {
  23
  24   arch-meson mesa-demos-$pkgver build \
  25     -D gles1=disabled \
  26     -D with-system-data-files=true
  27
  28   # Print config
  29   meson configure build
  30
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package_mesa-demos() {
  39   pkgdesc="Mesa demos"
  40   depends=('libgl' 'glu' 'freeglut' 'libdecor' 'libxkbcommon')
  41   install=mesa-demos.install
  42
  43   DESTDIR="$pkgdir" meson install -C build
  44
  45   # remove utils
  46   rm "${pkgdir}"/usr/bin/{glxinfo,glxgears,\
  47 eglinfo,eglgears_wayland,eglgears_x11,\
  48 eglkms,egltri_wayland,egltri_x11,\
  49 es2_info,es2gears_wayland,es2gears_x11,es2tri,\
  50 peglgears,xeglgears,\
  51 xeglthreads,vkgears}
  52
  53   install -Dm 0644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  54 }
  55
  56 package_mesa-utils() {
  57   pkgdesc="Essential Mesa utilities"
  58   depends=('libgl' 'libdecor' 'libxkbcommon-x11')
  59   provides=('glxinfo' 'glxgears'
  60             'eglinfo' 'eglgears'
  61             'es2info' 'es2gears')
  62
  63
  64   install -Dm 0755 build/src/egl/opengl/\
  65 {eglinfo,eglgears_wayland,eglgears_x11,\
  66 eglkms,egltri_wayland,egltri_x11,\
  67 peglgears,xeglgears,xeglthreads} -t "${pkgdir}/usr/bin/"
  68
  69   install -Dm 0755 build/src/egl/opengles2/\
  70 {es2_info,es2gears_wayland,es2gears_x11,es2tri} -t "${pkgdir}/usr/bin/"
  71
  72   install -Dm 0755 build/src/xdemos/{glxinfo,glxgears} -t "${pkgdir}/usr/bin/"
  73   install -Dm 0755 build/src/vulkan/vkgears -t "${pkgdir}/usr/bin/"
  74
  75   install -Dm 0644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  76 }