gnome-user-docs/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=gnome-user-docs
   5 pkgver=41.1
   6 pkgrel=1
   7 pkgdesc="User documentation for GNOME"
   8 url="https://gitlab.gnome.org/GNOME/gnome-user-docs"
   9 arch=(any)
  10 license=(FDL)
  11 depends=(yelp)
  12 makedepends=(yelp-tools git)
  13 groups=(gnome)
  14 _commit=11cf27a4d0bd69607b462e7713046ec9c4deb9dc  # tags/41.1^0
  15 source=("git+https://gitlab.gnome.org/GNOME/gnome-user-docs.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25   NOCONFIGURE=1 ./autogen.sh
  26 }
  27
  28
  29 build() {
  30   cd $pkgname
  31   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  32   make
  33 }
  34
  35 package() {
  36   cd $pkgname
  37   make DESTDIR="$pkgdir" install
  38 }