kdevelop/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   4
   5 pkgname=kdevelop
   6 pkgver=21.12.0
   7 _clangver=13.0.0
   8 pkgrel=1
   9 pkgdesc='C++ IDE using KDE technologies'
  10 arch=(x86_64)
  11 url='http://www.kdevelop.org/'
  12 license=(GPL)
  13 depends=(clang=$_clangver libksysguard kitemmodels knotifyconfig ktexteditor grantlee libkomparediff2 kcmutils threadweaver)
  14 makedepends=(extra-cmake-modules kdoctools kdevelop-pg-qt llvm qt5-tools plasma-framework krunner okteta boost purpose subversion astyle)
  15 optdepends=('konsole: embedded terminal'
  16             'git: Git support' 'subversion: SVN support'
  17             'gdb: GNU debugger support' 'lldb: LLDB debugger support'
  18             'qt5-doc: Qt documentation integration'
  19             'cmake: cmake integration'
  20             'meson: meson integration'
  21             'qt5-tools: qthelp plugin'
  22             'okteta: GNU debugger support'
  23             'plasma-framework: for the plasma addons'
  24             'purpose: patch review plugin'
  25             'astyle: astyle plugin'
  26             'cppcheck: code analyzer' 'heaptrack: memory profiler'
  27             'clazy: clazy analyzer plugin')
  28 conflicts=(kdevelop-qmljs kdevplatform)
  29 replaces=(kdevelop-qmljs kdevplatform kdevelop-clang-tidy)
  30 groups=(kde-applications kdevelop)
  31 source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
  32 sha256sums=('64337d5a3141171be920bb2c1be23556c0d2d6361b461a5ce4266f490f19619f'
  33             'SKIP')
  34 validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
  35               F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
  36               D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>
  37
  38 build() {
  39   cmake -B build -S $pkgname-$pkgver \
  40     -DBUILD_TESTING=OFF
  41   cmake --build build
  42 }
  43
  44 package() {
  45   DESTDIR="$pkgdir" cmake --install build
  46 }