librsvg/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=librsvg
   5 pkgver=2.52.4
   6 pkgrel=1
   7 epoch=2
   8 pkgdesc="SVG rendering library"
   9 url="https://wiki.gnome.org/Projects/LibRsvg"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(gdk-pixbuf2 pango)
  13 makedepends=(gobject-introspection vala gtk-doc git rust)
  14 provides=(librsvg-${pkgver%%.*}.so)
  15 _commit=2f6f58ef7edda386badf24d2beac153f0195723a  # tags/2.52.4^0
  16 source=("git+https://gitlab.gnome.org/GNOME/librsvg.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd librsvg
  21   git describe --tags | sed 's/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd librsvg
  26   NOCONFIGURE=1 ./autogen.sh
  27 }
  28
  29 # Use LTO
  30 export CARGO_PROFILE_RELEASE_LTO=true CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1
  31
  32 build() {
  33   cd librsvg
  34   ./configure --prefix=/usr --disable-static --enable-vala \
  35     --enable-gtk-doc
  36   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
  37   make
  38 }
  39
  40 check() {
  41   cd librsvg
  42   # Test suite is very dependent on the versions of
  43   # Cairo, Pango, FreeType and HarfBuzz
  44   make check || :
  45 }
  46
  47 package() {
  48   cd librsvg
  49   make DESTDIR="$pkgdir" install
  50 }
  51
  52 # vim:set sw=2 et: