libupnp/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: David Runge <dvzrv@archlinux.org>
   3 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   4 # Contributor: kastor <kastor@fobos.org.ar>
   5
   6 _name=pupnp
   7 pkgname=libupnp
   8 pkgver=1.14.12
   9 pkgrel=2
  10 pkgdesc='Portable Open Source UPnP Development Kit'
  11 url="https://pupnp.sourceforge.io/"
  12 arch=('x86_64')
  13 license=('BSD')
  14 depends=('glibc')
  15 makedepends=('cmake')
  16 provides=('libixml.so' 'libupnp.so')
  17 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${_name}/${_name}/archive/release-${pkgver}.tar.gz"
  18          libupnp-optional-static.patch)
  19 sha512sums=('aab17aa12f15d110bfab20cbcbae5f54926b6ca7a30bce10b9287cd39919a06a5e9f1493405e1d561c0d58ba46926f87009df891e4e4f37097df1c3c67635ca9'
  20             '7bae244c522f35261fdc07f0036a56eb319d6bff5a88d690e7563369184f7f39c30330e0d88967a84db8c22a1e9d1335dbc66d8758855fd8f9981c4f9ca28ddc')
  21 b2sums=('721c10f9fa4ffc60743b4ebf8be566ea595931cb1f2a2448d8e3cecfc787abfb855cb16256eaaa10ce6a901cd5e5b3d14672610841b2a718d5dd003ccfd3c2f0'
  22         'ef0d9e17d45fe378ef9f7b07c1b679ee4dbe6d9f1aee540123d08c709b092a4824218a863e0a3077e728c17131ae6d817295e44b4fc0cbbc75d372e62c7319f3')
  23
  24 prepare() {
  25   mv -v ${_name}-release-${pkgver} ${pkgname}-${pkgver}
  26
  27 # Make static libraries optional, partial backport of https://github.com/pupnp/pupnp/commit/a0622cb0199be1b5f86317fb3c9b4de59d3ac893
  28   patch -d ${pkgname}-${pkgver} -p1 < libupnp-optional-static.patch
  29 }
  30
  31 build() {
  32   cd ${pkgname}-${pkgver}
  33   cmake -DCMAKE_INSTALL_PREFIX=/usr \
  34         -DCMAKE_BUILD_TYPE='None' \
  35         -DUPNP_BUILD_STATIC=OFF \
  36         -Wno-dev \
  37         -B build \
  38         -S .
  39   make VERBOSE=1 -C build
  40 }
  41
  42 check() {
  43   cd ${pkgname}-${pkgver}
  44   make VERBOSE=1 -C build test
  45 }
  46
  47 package() {
  48   cd ${pkgname}-${pkgver}
  49   make -C build DESTDIR="${pkgdir}" install
  50   install -vDm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  51   install -vDm 644 {ChangeLog,README.md} \
  52     -t "${pkgdir}/usr/share/doc/${pkgname}"
  53 }
  54
  55 # vim: ts=2 sw=2 et: