python-pyparsing/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Alexander F Rødseth <xyproto@archlinux.org>
   3 # Contributor: Chris Brannon <cmbrannon79@gmail.com>
   4 # Contributor: Geoffroy Carrier <geoffroy.carrier@aur.archlinux.org>
   5 # Contributor: Arvid Ephraim Picciani <aep@exys.org>
   6 # Contributor: Michael Krauss <hippodriver@gmx.net>
   7
   8 pkgname=python-pyparsing
   9 pkgname=('python-pyparsing' 'python2-pyparsing')
  10 pkgver=2.4.7
  11 pkgrel=6
  12 pkgdesc='General parsing module for Python'
  13 arch=('any')
  14 url='https://github.com/pyparsing/pyparsing/'
  15 makedepends=('python-setuptools' 'python2-setuptools')
  16 license=('MIT')
  17 source=("https://github.com/pyparsing/pyparsing/archive/pyparsing_$pkgver.tar.gz")
  18 sha512sums=('c7a546729f86a2b5176e2482b566b9fd715b03e495aaef4d720b21307bb03f385dbc849247f8d266cb3d92be0a83c34ce4995b655ce85318355d5a0d42d6991e')
  19
  20 build() {
  21   cd pyparsing-pyparsing_$pkgver
  22   python setup.py build
  23   python2 setup.py build
  24 }
  25
  26 check() {
  27   cd pyparsing-pyparsing_$pkgver
  28   python unitTests.py
  29   python2 unitTests.py
  30 }
  31
  32 package_python-pyparsing() {
  33   depends=('python')
  34
  35   cd pyparsing-pyparsing_$pkgver
  36
  37   python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  38   install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  39 }
  40
  41 package_python2-pyparsing() {
  42   depends=('python2')
  43
  44   cd pyparsing-pyparsing_$pkgver
  45
  46   python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  47   install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  48 }
  49
  50 # vim:set ts=2 sw=2 et: