rasqal/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Tom Gundersen <teg@jklm.no>
   3 # Contributor: AndyRTR <andyrtr@archlinux.org>
   4 # Contributor: Lawrence Lee <valheru@facticius.net>
   5
   6 pkgname=rasqal
   7 epoch=1
   8 pkgver=0.9.33
   9 pkgrel=4
  10 pkgdesc="A library handling RDF query syntaxes, construction and execution"
  11 url="http://librdf.org/rasqal"
  12 license=('LGPL2.1')
  13 arch=('x86_64')
  14 depends=('glibc' 'libgcrypt' 'libgpg-error' 'mpfr' 'pcre')
  15 makedepends=('raptor' 'util-linux')
  16 provides=('librasqual.so')
  17 source=(http://download.librdf.org/source/${pkgname}-${pkgver}.tar.gz{,.asc})
  18 sha512sums=('05728682797470db9e51d156012e8fde9dec1554d107372faa11cbe6cdc3356e92386f4f8de6d7c41e3100b76f9b1c6809102a913829cddbd2ff29043c04d522'
  19             'SKIP')
  20 b2sums=('87bca86b2f0dceb0801f5a34dae9ae1f87d8a7d0dc1e03fdf04998a0d4885ed76be2719d3e01489a5510a26715bb093a75ce194cc42f3cedff88f64161d6a2fb'
  21         'SKIP')
  22 validpgpkeys=('F879F0DEDA780198DD08DC6443EC92504F71955A') # Dave Beckett <dave@dajobe.org>
  23
  24 prepare() {
  25   cd "${pkgname}-${pkgver}"
  26   autoreconf -vfi
  27 }
  28
  29 build() {
  30   cd "${pkgname}-${pkgver}"
  31   ./configure --prefix=/usr \
  32               --disable-static \
  33               --enable-release
  34   make
  35 }
  36
  37 check() {
  38   cd "${pkgname}-${pkgver}"
  39   make -k check || true # still fails some checks
  40 }
  41
  42 package() {
  43   depends+=('libraptor2.so' 'libuuid.so')
  44   cd "${pkgname}-${pkgver}"
  45   make DESTDIR="${pkgdir}" install
  46   install -vDm 644 {ChangeLog*,README,NEWS} \
  47     -t "${pkgdir}/usr/share/doc/${pkgname}/"
  48 }