sbsigntools/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   3 # Contributor: Mico Tischler <mt-ml at gmx dot net>
   4 # Contributor: Keshav Amburay <(the ddoott ridikulus ddoott rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>
   5
   6 pkgname=sbsigntools
   7 pkgver=0.9.4
   8 pkgrel=1
   9 pkgdesc="Tools to add signatures to EFI binaries and Drivers"
  10 arch=('x86_64')
  11 url="https://git.kernel.org/pub/scm/linux/kernel/git/jejb/sbsigntools.git/about"
  12 license=('GPL3')
  13 depends=('glibc' 'openssl')
  14 makedepends=('git' 'gnu-efi' 'help2man' 'libutil-linux')
  15 source=("git+https://git.kernel.org/pub/scm/linux/kernel/git/jejb/sbsigntools.git#tag=v${pkgver}?signed"
  16         "git+https://git.ozlabs.org/ccan")
  17 sha256sums=('SKIP'
  18             'SKIP')
  19 validpgpkeys=('D5606E73C8B46271BEAD9ADF814AE47C214854D6') # James Bottomley <jejb@kernel.org>
  20
  21 prepare() {
  22   cd ${pkgname}
  23   git submodule init
  24   git config submodule."lib/ccan.git".url "${srcdir}/ccan"
  25   git submodule update
  26   ./autogen.sh
  27 }
  28
  29 build() {
  30   cd "${pkgname}"
  31   ./configure --prefix="/usr" \
  32               --bindir="/usr/bin" \
  33               --sbindir="/usr/bin" \
  34               --libexecdir="/usr/lib" \
  35               --mandir="/usr/share/man" \
  36               --sysconfdir="/etc"
  37   make
  38 }
  39
  40 package() {
  41   depends+=('libuuid.so')
  42   cd "${pkgname}"
  43   make DESTDIR="${pkgdir}" install
  44   install -vDm 644 {AUTHORS,ChangeLog,NEWS,README} \
  45     -t "${pkgdir}/usr/share/doc/${pkgname}"
  46 }