appstream/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Jameson Pugh <imntreal@gmail.com>
   3 # Contributor: Tim Jester-Pfadt <t.jp<at>gmx.de>
   4
   5 pkgbase=appstream
   6 pkgname=(appstream appstream-qt)
   7 pkgver=0.16.2
   8 pkgrel=1
   9 pkgdesc='Provides a standard for creating app stores across distributions'
  10 arch=(x86_64)
  11 url='https://distributions.freedesktop.org/wiki/AppStream'
  12 license=(GPL)
  13 depends=(curl librsvg libyaml libxmlb)
  14 makedepends=(meson xmlto gobject-introspection gtk-doc qt5-tools itstool vala gperf)
  15 source=(https://www.freedesktop.org/software/appstream/releases/AppStream-$pkgver.tar.xz{,.asc}
  16         update-appstream-cache.hook)
  17 sha256sums=('f9cb80bd388fbf06be268afa7f2d65863c85d605ad874b905094f3982d03f232'
  18             'SKIP'
  19             '3a96a1479cfd18dad36c2ca3181aabe46af9bf772c00b965d86ec5f55cd0e0eb')
  20 validpgpkeys=(D33A3F0CA16B0ACC51A60738494C8A5FBF4DECEB) # Matthias Klumpp <matthias@tenstral.net>
  21
  22 build() {
  23   meson build AppStream-$pkgver \
  24     --prefix=/usr \
  25     --libexecdir=lib \
  26     -Dqt=true \
  27     -Dvapi=true \
  28     -Dcompose=true
  29   meson compile -C build
  30 }
  31
  32 package_appstream() {
  33   meson install --destdir "$pkgdir" -C build
  34
  35 # provided by -qt subpackage
  36   rm -r "$pkgdir"/usr/{include/AppStreamQt,lib/cmake,lib/libAppStreamQt.*}
  37
  38   install -Dm644 update-appstream-cache.hook "$pkgdir"/usr/share/libalpm/hooks/90-update-appstream-cache.hook
  39 }
  40
  41 package_appstream-qt() {
  42   pkgdesc='Qt5 interface for AppStream'
  43   depends=(appstream qt5-base)
  44
  45   meson install --destdir "$pkgdir" -C build
  46
  47 # provided by appstream
  48   rm -r "$pkgdir"{/etc,/usr/{bin,include/appstream{,-compose},lib/{appstreamcli-compose,girepository-1.0,libappstream*,pkgconfig},share}}
  49 }