f2fs-tools/trunk/PKGBUILD

   1 # Maintainer: Tobias Powalowski <tpowa@archlinux.org>
   2 # Contributor: Christian Hesse <mail@eworm.de>
   3
   4 pkgname=f2fs-tools
   5 _tag='64f2596142800c215cb40a658ebd5793ed37c936' # git rev-parse v${pkgver}
   6 pkgver=1.16.0
   7 pkgrel=1
   8 pkgdesc='Tools for Flash-Friendly File System (F2FS)'
   9 arch=('x86_64')
  10 url='https://git.kernel.org/pub/scm/linux/kernel/git/jaegeuk/f2fs-tools.git/about/'
  11 provides=('libf2fs.so' 'libf2fs_format.so')
  12 depends=('util-linux')
  13 makedepends=('git')
  14 license=('GPL')
  15 validpgpkeys=('D3452A79D8C2B4EAC656F4224014A87E824850D2') # Jaegeuk Kim <jaegeuk@kernel.org>
  16 source=("git+https://git.kernel.org/pub/scm/linux/kernel/git/jaegeuk/f2fs-tools.git#tag=${_tag}")
  17 sha256sums=('SKIP')
  18
  19 _backports=(
  20   # f2fs-tools: fix build error on lz4-1.9.4
  21   '19f77c6f6277a274434d6d8883f50e7955c6a8db'
  22 )
  23
  24 _reverts=(
  25 )
  26
  27 prepare() {
  28   cd "${pkgname}"
  29
  30   local _c
  31   for _c in "${_backports[@]}"; do
  32     if [[ $_c == *..* ]]; then
  33       git log --oneline --reverse "${_c}"
  34     else
  35       git log --oneline -1 "${_c}"
  36     fi
  37     git cherry-pick -n -m1 "${_c}"
  38   done
  39   for _c in "${_reverts[@]}"; do
  40     git log --oneline -1 "${_c}"
  41     git revert -n "${_c}"
  42   done
  43
  44   autoreconf -fi
  45 }
  46
  47 build() {
  48   cd "${pkgname}"
  49
  50   ./configure \
  51     --prefix=/usr \
  52     --sbindir=/usr/bin
  53   make
  54 }
  55
  56 package() {
  57   cd "${pkgname}"
  58
  59   make DESTDIR="${pkgdir}/" sbindir=/usr/bin install
  60
  61   # /usr/bin/sg_write_buffer is provided in sg3_utils
  62   rm "${pkgdir}"/usr/bin/sg_write_buffer
  63 }