libpng/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Contributor: dorphell <dorphell@archlinux.org>
   3 # Contributor: Travis Willard <travis@archlinux.org>
   4 # Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
   5
   6 pkgname=libpng
   7 pkgver=1.6.39
   8 pkgrel=1
   9 pkgdesc='A collection of routines used to create PNG format graphics files'
  10 arch=('x86_64')
  11 url='http://www.libpng.org/pub/png/libpng.html'
  12 license=('custom')
  13 depends=('zlib' 'sh')
  14 options=('debug')
  15 validpgpkeys=('8048643BA2C840F4F92A195FF54984BFA16C640F') # Glenn Randers-Pehrson (mozilla) <glennrp@gmail.com>
  16 source=("https://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.xz")
  17 sha256sums=('1f4696ce70b4ee5f85f1e1623dc1229b210029fa4b7aee573df3e2ba7b036937')
  18
  19 build() {
  20   cd $pkgname-$pkgver
  21
  22   ./configure \
  23     --prefix=/usr \
  24     --disable-static
  25   make
  26 }
  27
  28 check() {
  29   cd $pkgname-$pkgver
  30
  31   make check
  32 }
  33
  34 package() {
  35   cd $pkgname-$pkgver
  36
  37   make DESTDIR="$pkgdir" install
  38
  39   install -D -m0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  40
  41   cd contrib/pngminus
  42   make PNGLIB_SHARED="-L$pkgdir/usr/lib -lpng" CFLAGS="$CFLAGS" LDFLAGS="$LDFLAGS" png2pnm pnm2png
  43   install -m0755 png2pnm pnm2png "$pkgdir/usr/bin/"
  44 }