wayland-protocols/trunk/PKGBUILD

   1 # Maintainer: Sébastien Luttringer <seblu@seblu.net>
   2
   3 pkgname=wayland-protocols
   4 pkgver=1.31
   5 pkgrel=1
   6 pkgdesc='Specifications of extended Wayland protocols'
   7 arch=('any')
   8 url='https://wayland.freedesktop.org/'
   9 license=('MIT')
  10 makedepends=('wayland' 'meson' 'ninja')
  11 validpgpkeys=('8307C0A224BABDA1BABD0EB9A6EEEC9E0136164A'  # Jonas Ådahl
  12               'A66D805F7C9329B4C5D82767CCC4F07FAC641EFF') # Daniel Stone
  13 source=("https://gitlab.freedesktop.org/wayland/$pkgname/-/releases/$pkgver/downloads/$pkgname-$pkgver.tar.xz"{,.sig})
  14 sha256sums=('a07fa722ed87676ec020d867714bc9a2f24c464da73912f39706eeef5219e238'
  15             'SKIP')
  16
  17 prepare() {
  18   cd $pkgname-$pkgver
  19   # apply patch from the source array (should be a pacman feature)
  20   local src
  21   for src in "${source[@]}"; do
  22     src="${src%%::*}"
  23     src="${src##*/}"
  24     [[ $src = *.patch ]] || continue
  25     echo "Applying patch $src..."
  26     patch -Np1 < "../$src"
  27   done
  28 }
  29
  30 build() {
  31   meson build $pkgname-$pkgver --buildtype=release --prefix=/usr
  32   ninja -C build
  33 }
  34
  35 check() {
  36   ninja -C build test
  37 }
  38
  39 package() {
  40   DESTDIR="$pkgdir" ninja -C build install
  41   set -x
  42   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m 644 "$pkgname-$pkgver/COPYING"
  43 }
  44
  45 # vim:set ts=2 sw=2 et: