compiler-rt14/trunk/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: Jan "heftig" Steffens <jan.steffens@gmail.com>
   3
   4 pkgname=compiler-rt14
   5 pkgver=14.0.6
   6 pkgrel=2
   7 pkgdesc="Compiler runtime libraries for clang 14"
   8 arch=('x86_64')
   9 url="https://compiler-rt.llvm.org/"
  10 license=('custom:Apache 2.0 with LLVM Exception')
  11 depends=('gcc-libs')
  12 makedepends=('llvm14' 'cmake' 'ninja' 'python')
  13 # Build 32-bit compiler-rt libraries on x86_64 (FS#41911)
  14 makedepends_x86_64=('lib32-gcc-libs')
  15 options=('staticlibs')
  16 _source_base=https://github.com/llvm/llvm-project/releases/download/llvmorg-$pkgver
  17 source=($_source_base/compiler-rt-$pkgver.src.tar.xz{,.sig}
  18         remove-include-linux-fs.h.patch)
  19 sha256sums=('88df303840ca8fbff944e15e61c141226fe79f5d2b8e89fb024264d77841a02e'
  20             'SKIP'
  21             '34ed866e313e4580130a50118a4410d36fa0159123982521b6ef049439fc32ad')
  22 validpgpkeys=('474E22316ABF4785A88C6E8EA2C794A986419D8A') # Tom Stellard <tstellar@redhat.com>
  23
  24 prepare() {
  25   cd compiler-rt-$pkgver.src
  26   mkdir build
  27
  28   # https://github.com/llvm/llvm-project/issues/56421
  29   patch -Np2 -i ../remove-include-linux-fs.h.patch
  30 }
  31
  32 build() {
  33   cd compiler-rt-$pkgver.src/build
  34
  35   local cmake_args=(
  36     -G Ninja
  37     -DCMAKE_BUILD_TYPE=Release
  38     -DCMAKE_INSTALL_PREFIX=/usr/lib/llvm14
  39     -DCMAKE_SKIP_RPATH=ON
  40     -DCOMPILER_RT_INSTALL_PATH=/usr/lib/llvm14/lib/clang/$pkgver
  41   )
  42   cmake .. "${cmake_args[@]}"
  43   ninja
  44 }
  45
  46 package() {
  47   cd compiler-rt-$pkgver.src/build
  48
  49   DESTDIR="$pkgdir" ninja install
  50   install -Dm644 ../LICENSE.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  51 }
  52
  53 # vim:set ts=2 sw=2 et: