gcab/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gcab
   5 pkgver=1.5
   6 pkgrel=1
   7 pkgdesc="A GObject library to create cabinet files"
   8 url="https://wiki.gnome.org/msitools"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(glib2)
  12 makedepends=(gobject-introspection vala git gtk-doc meson)
  13 provides=(libgcab-1.0.so)
  14 _commit=d8054af4381dcef17ae691775c96a60116823047  # tags/v1.5^0
  15 source=("git+https://gitlab.gnome.org/GNOME/gcab.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd gcab
  20   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd gcab
  25 }
  26
  27 build() {
  28   arch-meson gcab build
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package() {
  37   meson install -C build --destdir "$pkgdir"
  38 }