tumbler/trunk/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: Andreas Radke <andyrtr@archlinux.org>
   3 # Contributor: Jan Jezek <honzin.jezek@gmail.com>
   4
   5 pkgname=tumbler
   6 pkgver=4.18.1
   7 pkgrel=1
   8 pkgdesc="Thumbnail service implementing the thumbnail management D-Bus specification"
   9 arch=('x86_64')
  10 url="https://docs.xfce.org/xfce/tumbler/start"
  11 license=('GPL2' 'LGPL')
  12 groups=('xfce4')
  13 depends=('libxfce4util' 'gdk-pixbuf2')
  14 makedepends=('intltool' 'python' 'ffmpegthumbnailer' 'poppler-glib' 'libgsf'
  15              'libgepub' 'libopenraw' 'freetype2')
  16 optdepends=('ffmpegthumbnailer: video thumbnails'
  17             'poppler-glib: PDF thumbnails'
  18             'libgsf: ODF thumbnails'
  19             'libgepub: EPUB thumbnails'
  20             'libopenraw: RAW thumbnails'
  21             'freetype2: font thumbnails')
  22 backup=('etc/xdg/tumbler/tumbler.rc')
  23 source=(https://archive.xfce.org/src/xfce/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
  24 sha256sums=('ff61981a9c0af5fec768d4f1552bd63948a64b2f4db1c2e3d93c31c19dc563a0')
  25
  26 build() {
  27   cd $pkgname-$pkgver
  28
  29   ./configure \
  30     --prefix=/usr \
  31     --sysconfdir=/etc \
  32     --disable-debug \
  33     --disable-gstreamer-thumbnailer
  34   make
  35 }
  36
  37 package() {
  38   cd $pkgname-$pkgver
  39   make DESTDIR="$pkgdir" install
  40 }
  41
  42 # vim:set ts=2 sw=2 et: