totem/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=totem
   5 pkgver=3.38.2
   6 pkgrel=1
   7 pkgdesc="Movie player for the GNOME desktop based on GStreamer"
   8 url="https://wiki.gnome.org/Apps/Videos"
   9 arch=(x86_64)
  10 license=(GPL2 custom)
  11 depends=(totem-plparser iso-codes libpeas clutter-gtk clutter-gst grilo
  12          gsettings-desktop-schemas dconf python-gobject python-xdg gnome-desktop
  13          gst-plugins-base gst-plugins-good gst-plugins-bad)
  14 makedepends=(libnautilus-extension itstool docbook-xsl python-pylint
  15              gobject-introspection git appstream-glib gtk-doc meson intltool)
  16 optdepends=('gst-plugins-ugly: Extra media codecs'
  17             'gst-libav: Extra media codecs'
  18             'grilo-plugins: Media discovery'
  19             'python-dbus: MPRIS plugin')
  20 groups=(gnome)
  21 conflicts=(totem-plugin)
  22 replaces=(totem-plugin)
  23 _commit=5bcc171feaf6127dcd2c09289063adef662d33b2  # tags/V_3_38_2^0
  24 source=("git+https://gitlab.gnome.org/GNOME/totem.git#commit=$_commit"
  25         "git+https://gitlab.gnome.org/GNOME/libgd.git")
  26 sha256sums=('SKIP'
  27             'SKIP')
  28
  29 pkgver() {
  30   cd $pkgname
  31   git describe --tags | sed 's/^V_//;s/-fixed//;s/_/./g;s/-/+/g'
  32 }
  33
  34 prepare() {
  35   cd $pkgname
  36
  37   git submodule init
  38   git submodule set-url subprojects/libgd "$srcdir/libgd"
  39   git submodule update
  40 }
  41
  42 build() {
  43   arch-meson $pkgname build -D enable-gtk-doc=true
  44   meson compile -C build
  45 }
  46
  47 package() {
  48   meson install -C build --destdir "$pkgdir"
  49   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/COPYING
  50 }