gst-python/repos/testing-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Jan de Groot <jgc@archlinux.org>
   4
   5 pkgname=gst-python
   6 pkgver=1.18.5
   7 pkgrel=3
   8 pkgdesc="Multimedia graph framework - python bindings"
   9 url="https://gstreamer.freedesktop.org/"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(python-gobject gst-plugins-base-libs)
  13 makedepends=(git meson)
  14 _commit=3d75c6b1eefc1a4190f58ac8d4610535f1acca3f  # tags/1.18.5^0
  15 source=("git+https://gitlab.freedesktop.org/gstreamer/gst-python.git#commit=$_commit"
  16         0001-python-Avoid-treating-float-as-int.patch)
  17 sha256sums=('SKIP'
  18             '62f301faddb4c713bd21b2da95daec9b73b903da168d7c9649550a0678a1ff77')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27   patch -Np3 -i ../0001-python-Avoid-treating-float-as-int.patch
  28 }
  29
  30 build() {
  31   arch-meson $pkgname build
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41   python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  42   python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
  43 }